Per visualizzare un determinato popup, basta cliccare col tasto destro del mouse in una finestra, ed apparirà il rispettivo popup. In questi si possono inserire comandi di ogni genere, come oppare un utente, entrare in un canale, ecc. La sintassi è:

<menuitem>:<comandi>

Esempio:

Per aiuti:/join #tuttoirc

Le parole che precedono i : sono in pratica il testo che apparirà nel popup, mentre quello che segue i : i comandi che saranno eseguiti. In questo caso "Per aiuti" è il menuitem e "/join #tuttoirc" il comando.

Nota. La sintassi dei comandi segue la stessa procedura usata per gli aliases.

Per creare un sottomenu si usa il carattere . (punto)

Entra in un canale
.Per aiuti:/join #tuttoirc
.Per trovare amici:/join #^maya^
.Scegli un canale:/join #$?="In quale canale vuoi entrare?"

Il nome del sottomenu in questo caso è "Entra in un canale" e tutto quello che segue il . fa parte di questo.

Si possono creare anche sottomenu nei sottomenu in questo modo:

Entra in un canale
.Per aiuti
..Irc:/join #tuttoirc
..help:/join #irc.help
.Per trovare amici:/join #^maya^
.Scegli un canale:/join #$?="In quale canale vuoi entrare?"

Il carattere - serve per creare linee che separano due menuitems:

Funzioni
.Edita testo:/run notepad.exe testo.txt
.say?: /say $?
.azione?:/me $?
-
Nomi
.#irc.help: /names #irc.help
.#tuttoirc: /names #tuttoirc
.nomi?:/names $?="In quale canale?"

Per usare un popup situato nella listbox di un canale è necessario selezionare prima un nick, e poi cliccare col tasto destro del mouse.

Chi è?:/whois $1
-
Modi
.Op:/mode # +o $1
.Deop:/mode # -o $1
.Kick, Ban:/kick # $1 | /ban $1
-
DCC Send:/dcc send $1
DCC Chat:/dcc chat $1
-
Bacio:/me da un grande bacio a $1
Query:/query $1 Hey! Ciao! Come va...?

Anche per i popups è possibile creare comandi su più linee, e come negli aliases basta usare {}.

Controllo {
if ($1 == $me) echo Questo sei tu!
else echo Questo non sei tu!
}

Usato nella listbox questo script controlla se il nick selezionato, quindi $1, siete voi, e se lo siete vi scrive "Questo sei tu!", altrimenti, se il nick è diverso dal vostro, scrive "Questo non sei tu!".

Si lavora allo stesso modo anche per gli altri menu (menubar, query/chat, ecc.). Nel menubar però la prima parola o frase scritta andrà a sostituire il Commands di default del mIRC.

Remote Scripts
È possibile creare popups anche dai remote, basta specificare di quale popup menu si tratta:

menu status {
Server
.Links:/links
.Lusers:/lusers
.Motd:/motd
.Ora:/time
}

Questo aggiunge nel menu status il sottomenu sopra detto.

Naturalmente lo stesso discorso vale per il canale, la nicklist, ecc. Basta scrivere al posto di status, per esempio, nicklist, channel, o chi per lui.

I popups possono essere inseriti anche nelle finestre (custom windows). Basta aggiungere dopo menu il nome della finestra:

menu @test {
dclick:/echo Doppio Click!
}

Il comando citato verrà realizzato quando voi farete un doppio click (dclick) nella finestra.
È possibile fare la stessa cosa anche per più finestre:

menu @cani,@gatti,@capre {
dclick: /echo doppio click in $active
close: window -c $active
}

Si può anche usare l'identificatore $menu, che si riferisce al popup associato allo script eseguito. Questo permette di cambiare il popup a seconda se si tratta di un canale, una query, ecc. Esempio:

menu query,nicklist {
$iif($menu == nicklist,Op):/mode # +o $$1
}

Menu Styles
Con l'dentificatore $style(N) è possibile inserire all'intero di un menuitem un check $style(1), oppure disabilitare il menuitem $style(2), o tutti e due $style(3).

menu status {
$iif($server == $null,$style(2)) Informazioni Server
.Motd:/motd
.Time:/time
}

Questo script crea un sottomenu nel popup dello status che si abilita solo quando siete connessi ad un server.